How to create a board game - Printable Version

Code:
constant GRID = 8 ' number of rows and columns.

constant SQUARE = 53 ' size of each square.



set window "test", 640, 480

set redraw off



' create 8x8 array filled with zeroes.

board = fill(0, GRID, GRID)

' place pieces.

for y = 0 to 2  for x = 0 to GRID - 1

    if (y + x)%2 = 1  board[x][y] = 1

    if (GRID - 1 - y + x)%2 = 1  board[x][GRID - 1 - y] = 2

next

' center board in window.

boardX = (width(primary) - GRID*SQUARE)/2

boardY = (height(primary) - GRID*SQUARE)/2



' set to 1 or 2 when a piece has been picked up.

holdingPiece = 0

' original position of picked up piece.

originalPieceX = 0

originalPieceY = 0



' loop until user presses escape.

while not keydown(KEY_ESCAPE, true)

    ' check if mouse is inside board.

    mx = mousex()

    my = mousey()

    gridX = mx - boardX

    gridY = my - boardY

    if gridX >= 0 and gridX < GRID*SQUARE and gridY >= 0 and gridY < GRID*SQUARE

        ' convert to grid coordinates.

        gridX = int(gridX/SQUARE)

        gridY = int(gridY/SQUARE)

        ' click?

        if mousebutton(0, true)

            ' not holding a piece?

            if not holdingPiece

                ' any piece at that position?

                if board[gridX][gridY]

                    ' store information about the piece.

                    holdingPiece = board[gridX][gridY]

                    originalPieceX = gridX

                    originalPieceY = gridY

                    ' remove piece from board.

                    board[gridX][gridY] = 0

                endif

            ' already holding piece.

            else

                ' spot empty?

                if not board[gridX][gridY]

                    ' same position or valid distance for move? here both players can move up and

                    ' down. only "kings" should be able to do that.

                    dx = |gridX - originalPieceX|

                    dy = |gridY - originalPieceY|

                    if dx = 0 and dy = 0 or dx = 1 and dy = 1 

                        ' put piece down.

                        board[gridX][gridY] = holdingPiece

                        holdingPiece = 0

                    endif

                endif

            endif

        endif

    endif



    ' draw.

    set color 0, 0, 0

    cls

        

    ' draw board.

    for y = 0 to GRID - 1

        for x = 0 to GRID - 1

            ' this formula gives a chess pattern.

            if (y + x)%2  set color 64, 64, 64

            else  set color 208, 208, 208

            draw rect boardX + x*SQUARE, boardY + y*SQUARE, SQUARE, SQUARE, true

            ' any piece?

            if board[x][y]

                DrawPiece(board[x][y], boardX + (x + 0.5)*SQUARE, boardY + (y + 0.5)*SQUARE)

            endif

        next

    next

    

    ' Draw picked up piece.

    if holdingPiece  DrawPiece(holdingPiece, mx, my)

    

    redraw

    fwait 60

wend



function DrawPiece(player, x, y)

    if player = 1  set color 240, 240, 240

    else  set color 32, 32, 32

    draw ellipse x, y, SQUARE/2 - 4, SQUARE/2 - 4, true

    set color 0, 0, 0

    draw ellipse x, y, SQUARE/2 - 4, SQUARE/2 - 4, false

endfunc